GRABS Übungsaufgaben RISC-V als Instruction Set Architecture Assembler programmieren

Assembler programmieren

a)

Level 1: Wissen

Assembly-Code beinhaltet Ausdrücke wie .globl _start, .data und .text. Was bedeuten diese Ausdrücke und warum sind sie wichtig?

Lösung

_start ist per Konvention der Einstiegspunkt für das Programm
.globl _start gibt an, dass dies ein globales Label ist, das auch für weitere verknüpfte Dateien sichtbar ist
.data und .text sind Bereiche im Speicher, die Daten und Anweisungen enthalten

b)

Level 3: Anwenden

Übersetzen Sie diesen C-Code in Assembler und erklären Sie, was er macht. Das Ergebnis soll in Register a0 gespeichert werden.

 1int main() {
 2    int a = 10;
 3    int b = 13;
 4    
 5    if (a < b) {
 6        return b - a;
 7    } else {
 8        return a - b;
 9    }
10}

Hinweis: Nutzen Sie den QtRvSim zum Testen und vergessen Sie nicht, Ihre Lösung zu kommentieren und zu speichern.

Lösung

 1.globl _start
 2.text  
 3
 4_start:
 5    li t0, 10        # Lade a in t0
 6    li t1, 13        # Lade b in t1
 7    blt t0, t1, then # if (a < b)
 8    sub a0, t0, t1   # a - b
 9    j end  
10
11then:
12    sub a0, t1, t0   # b - a
13    
14end:
15    ebreak

c)

Level 3: Anwenden

Schreiben Sie ein Assembler-Programm für RISC-V, das die Multiplikation von 105 und 90 berechnet. Das Ergebnis soll in Register a0 gespeichert werden. Nutzen Sie Bit-Shiften für die Multiplikation und nutzen Sie das Template.

 1.globl _start
 2.text
 3
 4_start:
 5    li a0, 0   # Ergebnis (a)
 6    li t0, 105 # Zahl 1 (x)
 7    li t1, 90  # Zahl 2 (y)
 8
 9# Hier kommt Ihr Code.
10
11end:
12    ebreak

Lösung

Die naive Variante des Algorithmus addiert die erste Zahl einfach so oft zum Ergebnis, wie es die zweite Zahl vorgibt. Mit Hilfe des Bit-Shiftens lässt sich allerdings eine bessere Laufzeit erzielen. Der „Shift-and-Add“-Ansatz (vgl. Wikipedia-Beitrag zu Multiplikationsarten) ist weit verbreitet und kann wie folgt in Pseudocode ausgedrückt werden:

 1FUNKTION mul(x, y) {
 2    a = 0; // Akkumulator
 3    
 4    SOLANGE (y != 0) {
 5        // LSB = least significant bit
 6        WENN (LSB von y == 1) { 
 7            a = a + x;
 8        }
 9            
10        x << 1;
11        y >> 1;
12    }
13    RÜCKSPRUNG; // oder Programmende, je nach Kontext
14}

 1.globl _start
 2.text
 3
 4_start:
 5    li a0, 0           # Ergebnis (a)
 6    li t0, 105         # Zahl 1 (x)
 7    li t1, 90          # Zahl 2 (y)
 8loop:
 9    beq t1, zero, end  # springe zum Ende wenn y == 0
10    andi t2, t1, 1     # LSB von y
11    beq t2, zero, else # springe zu else wenn LSB(y) == 0
12    add a0, a0, t0     # a = a + x
13else:
14    slli t0, t0, 1     # x << 1
15    srli t1, t1, 1     # y >> 1
16    j loop
17end:
18    ebreak

Lernziele

In dieser Aufgabe …

wiederholen die Studierenden Label und Direktiven in Assembler.
üben die Studierenden die Übersetzung von Hochsprachen zu Assembler.